RioLab

  • Aumenta dimensione caratteri
  • Dimensione caratteri predefinita
  • Diminuisci dimensione caratteri
Home Articoli MS Excel Calcolo paghe con festivo

Calcolo paghe con festivo

E-mail Stampa PDF

Domanda

In un foglio paga dovrei calcolare le paghe sulla base delle ore lavorate tenendo conto che le prime otto ore sono ordinarie e vanno moltiplicate per la paga oraria ordinaria, mentre le successive, ovvero gli straordinari, e
quelle lavorate nei giorni festivi (sabato, domenica e festività) vanno moltiplicate per la paga straordinaria.
Nella tabella vorrei tenere in due celle separate le ore lavorate la mattina e il pomeriggio.
Che formula devo usare?


Nel mio caso ho realizzato un foglio paga così strutturato:
in [A1] data;
in [B1] e [C1] ora di entrata e uscita mattina;
in [D1] e [E1] ora di entrata e uscita pomeriggio;
in [F1] e [G1] ho rispettivamente il computo delle ore lavorate la mattina e il pomeriggio.

 
Risposta1 (di Giovanna Arcadu)
 


Nel presupposto che la prima riga contenga i titoli delle colonne, innanzitutto integra la tabella con i seguenti parametri
in [H2] : il costo della paga oraria ordinaria
in [I2] : il costo della paga oraria straordinaria e festiva
in [J2] : il numero di ore massime ordinarie
in [K2:K10] le date delle feste al cui intervallo è stato attribuito il nome "feste".

in [L2] : la seguente formula:

=SE(O(RESTO(A2;7)<2;VAL.NUMERO(CONFRONTA(A2;feste;0)));(F2+G2)*24*I2;SE((F2+G2)*24<=J2;(F2+G2)*24*H2;SOMMA(H2*J2;((F2+G2)*24-J2)*I2)))

Per considerare i festivi devi definire un nome per un intervallo, dove vuoi tu, che contenga l'elenco delle festività che dovrai digitare. Io ho denominato tale intervallo, "feste".

Per definire un nome:
Menu inserisci> nome> definisci:
nomi nella cartella di lavoro: feste (attenzione, non lasciare spazi nel nome che scegli)
Riferito a: =Foglio1!$K$2:$K$10 (è solo un esempio dell'intervallo in cui digitare le festività).
 

 
Risposta2 (di cucchiaino)

 

Rispettando i parametri di cui alla Risposta1 di Giovanna, per il calcolo suggerirei la seguente formula:

=SE(O(RESTO(A2;7)<2;CONTA.SE(feste;A2));(F2+G2)*24*I2;H2*((F2+G2)*24)+((F2+G2)*24>J2)*(((F2+G2)*24)-J2)*(I2-H2))
 
che è la stessa di Giovanna con alcune semplificazioni.
 

 
Risposta3 (di MAO)

 

Volendo risparmiare qualche carattere nella formula di Cucchiaino si può utilizzare anche questa formula:

=SE(O(RESTO(A2;7)<2;CONTA.SE(feste;A2));(F2+G2)*24*I2;H2*(F2+G2)*24+MAX(0;(F2+G2)*24-J2)*(I2-H2))
 
 
 


Sistema operativo: WIN32

Applicazioni: Excel 97, Excel 2000, Excel 2002/XP, Excel 2003, Excel 2007

 

Allegati:
FileDescrizioneDimensione del File
Scarica questo file (CalcoloPagheFestivi.xls)Calcolo paghe con festivi 38 Kb
 

Pubblicità

Link consigliati: