RioLab

  • Aumenta dimensione caratteri
  • Dimensione caratteri predefinita
  • Diminuisci dimensione caratteri
Home Articoli MS Excel Contare o estrarre un pezzo di stringa

Contare o estrarre un pezzo di stringa

E-mail Stampa PDF

DOMANDA:

Ponendo di avere una stringa con scritto TOPOLINO*PIPPO*PLUTO , vorrei estrarre la parola intera dopo l'ultimo asterisco e trovare il numero di caratteri che la compongono.

   

RISPOSTA 1 (a cura di Maurizio Borrelli):

La seguente formula estrae la stringa PLUTO:

=SE(VAL.ERR(RICERCA("|";SOSTITUISCI(A1;"*";"|";LUNGHEZZA(A1)-LUNGHEZZA(SOSTITUISCI(
A1;"*";"")))));A1;STRINGA.ESTRAI(A1;RICERCA("|";SOSTITUISCI(A1;"*";"|";
LUNGHEZZA(A1)-LUNGHEZZA(SOSTITUISCI(A1;"*";""))))+1;LUNGHEZZA(A1)))

una volta ottenuta la stringa basta calcolarne la lunghezza con la funzione LUNGHEZZA(stringa).

  

RISPOSTA 2 (a cura di Ignazio Putignano):

Per calcolare il numero di caratteri, se dal conteggio vuoi escludere l'asterisco, usa la formula matriciale (da immettere premendo Ctrl+Maiusc+Invio):

 =LUNGHEZZA(A1)-MAX((STRINGA.ESTRAI(A1;RIF.RIGA(
INDIRETTO("A1:A"&LUNGHEZZA(A1)));1)="*")
*RIF.RIGA(INDIRETTO("A1:A"&LUNGHEZZA(A1))))

  Se invece vuoi includere l'asterisco, aggiungi 1 alla formula.

 

RISPOSTA 3 (a cura di Barbara Bonavota):

La seguente formula non matriciale estrae la stringa PLUTO:

=DESTRA(A1;1+LUNGHEZZA(A1)-TROVA("|";SOSTITUISCI
("*"&A1;"*";"|";1+LUNGHEZZA(A1)-LUNGHEZZA
(SOSTITUISCI(A1;"*";"")))))

 quest'altra calcola il numero di caratteri che la compongono

=1+LUNGHEZZA(A1)-TROVA("|";SOSTITUISCI
("*"&A1;"*";"|";1+LUNGHEZZA(A1)-LUNGHEZZA
(SOSTITUISCI(A1;"*";""))))

 
Sistema operativo: WIN32
Applicazioni: Excel 97, Excel 2000, Excel 2002/XP, Excel 2003, Excel 2007

 

Ultimo aggiornamento Giovedì 20 Agosto 2009 18:03  

Pubblicità

Link consigliati: